手把手教你编公式之8–2020.12.12更新（保真用图片，有价值的评论将转为“用户评论”）
（往下翻看内容和评论）
手把手教你学会编公式之8:
连续N天收阳线：
分步走：
1.收阳线：
就是收盘价大于开盘价：
A1:=C>O;
2.连续N天：
就是数数啊：用COUNT.
一起写来：
N:=5;
A1:=C>O;
XG:COUNT(A1,N)=N;
这里有一个现成的函数可用，效果稍有区别：
N:=5;
XG:UPNDAY(C,N);
效果见下图：
主动参与动手做：
加入“放量2倍”怎么做？
手把手教你学会编公式之7（复习）：
10个交易日内，涨幅大于9.9%（涨停）的天数：
COUNT(C/REF(C,1)>1.099,10)>=2;
复习题1:加入放量二倍：
肯定是比前一日或几日的放量，那么比前一日放量2倍的表达：
V>REF(V,1)*2;
把它加入上面的数数😄：
XG: COUNT(C/REF(C,1)>1.099,10)>=2 AND V>REF(V,1)*2;
思考题：换成缩量如何表达？
手把手教你学会编公式之六：
一、继续学习“COUNT”函数：
统计（说白了就是：数数）；
格式：COUNT(X,N);
统计N周期内满足X条件的周期数；
后面要跟”>=“某个数值，否则，单独用会显示计算失败；
例子：
10个交易日内，涨幅大于9.9%（涨停）的天数：
COUNT(C/REF(C,1)>1.099,10)>=2;
（注：计算十天内，收盘价比前一天上涨百十的天数大于等于2的情况。—-其实就是计算是否有2个涨停。）
COUNT(C/REF(C,1)>N3,N1)>=N2;
一般都要与其它指标结合来用，效果才佳。
练习题1:请加入放量2倍；
练习题2:请加入缩量2倍；
请大家积极参与练习，勤练才能快速掌握。
快来在评论中发表你的练习吧。谢谢。
用户评论：
我是这么理解的：收盘价小于前一天的收盘价，而这一天是前30天的最低价。不必较真字眼，会用就好，用多了就理解了许多。谢谢提问。
七讲预告：继续一些函数的学习。
手把手教你学会编公式之五：
作业5:超跌的设计：
（注意：超跌是有原因的，因而风险也是不少的，为保险，应该在实践中加入市盈率或市净率等指标来过滤。）
1、今天用到一个求最低值的函数：
LLV(X,N):求最低值
函数用法：LLV(X,N),求N周期内X最低值，N=0则从第一个有效值开始。
函数实际应用举例：
LLV(LOW,30)表示求30周期内最低价的最低值;
LLV(VOL,10)表示求10周期内成交量的最低值；
以上两项拿来用：
A1:=LLV(L,30);
A2:=LLV(V,10);
（1）加入股价是30天以来新低如何？
A3:=C<REF(LLV(C,30),1);
（注解：收盘价小于前30天的最低价。）
（2）再加入两天内,累计下跌等于或超过20%选股.
A4:=(REF(C,2)-C)/C>=0.2;
（注解：前天减今日收盘价，除于收盘价大于等于20%—-这就是说前天的价格比今天的价格高出20%，也就是说：二天内价格下跌了20%.）
A1:=LLV(L,30);
A2:=LLV(V,10);
A3:=C<REF(LLV(C,30),1);
A4:=(REF(C,2)-C)/C>=0.2;
XG: A1 AND A2 AND A3 AND A4;
以下是参数版：
A1:=LLV(L,N1);
A2:=LLV(V,N2);
A3:=C<REF(LLV(C,N3),1);
A4:=(REF(C,N4)-C)/C>N5;
XG: A1 AND A2 AND A3 AND A4;
以上测试通过。
以后讲课会越来越复杂，有不懂的，一是往下翻复习以前的基础知识；二是，如果还是不懂，请留言讨论吧，谢谢。
六讲预告：一些有用的函数（可以留言提出，看看需要哪种？）。
用户评论：
趁着行情不好，好好学习.
阿若:
继续继续，期待...
手把手教你学会编公式之四：
作业4: 股价从30日均线起涨不久后又缩量回调至30日均线的上方附近—-如何表达？
让我们分步走：
1、（一般都指比昨日）缩量—-如何表达？
—-就是今日的量”V”比昨日的量”REF(V,1)”小：
V<REF(V,1);
A1:=V<REF(V,1);
2、回调—理解为：收阴，就是收阳表达的反向：
C<O;
A2:=C<O;
3、回调至30日均线的上方附近—-那就是收盘价“C”依然大于30日均线”MA(C,30);
C>MA(C,30);
A3:=C>MA(C,30);
4、现在来讨论一个问题：
回调至30日均线的上方附近—-需经历一段时间才稳定，那么，这个回调经历的过程用什么表达？
答案是：天数；
用到一个数数的函数：COUNT;
用它来限制回调的时间段；
格式为：COUNT(某值,N1)>=N2;
N1和N2是天数的表达，可以一致，也可以不一样；
那么：缩量回调用天数来限制，就可以这样：
COUNT(A1 AND A2,N1)>=N2;
——就是数缩量且收阴的天数—-一般来说，天数越长越靠谱，过滤掉了不稳定，可以多试几个天数，以达最佳。
5、股价从30日均线起涨不久后又缩量回调至30日均线的上方附近的完形表达：
A1:=V<REF(V,1);
A2:=C<O;
A3:=C>MA(C,N3);
A4:=COUNT(A1 AND A2,N1)>=N2;
XG: A4 AND A3;
以上测试通过
如果换成二天呢？
可以试一试。
多利用参数调整，会大有不同啊。
好啦，多练习啊。
用户评论摘抄：
锋：
继续磨是否之前中长线看好的观点会改变呢？Shan 哥
shan:
现在还不是下结论的时候，要看最后一关：2818–年线附近的支撑力度。
五讲预告：选超跌如何设计？
手把手教你学会编公式之三：
作业3: 今天的量是5天平均的 2倍以上且收阳——如何表达：
（1）MA—-平均的意思；
我们已经知道了30日均线的表达—-
MA(C,30);
那么5天均量的表达就可以用替换法直接得到了，格式是一样的：
MA(V,5);
(2) 那么，今天的量—“V”是5天均量—“MA(V,5)”的2倍以上—表达：
V>MA(V,5)*2;
（3）收阳—-收盘价“C”大于开盘价“O”:
C>O;
(4) 今天的量 是5天平均的 2倍以上且收阳的完形表达：
V>MA(V,5)*2 AND C>O;
现在有一个小问题：如果总是用AND 下去，会是一大串，不简洁啊。
思路就是：把它们分别打包命名。
我习惯用A系列来命名。
A1:=（格式—-“:”加“=”）
A1:=V>REF(V,1)*3.0;
{把“今日比前日放量3倍以上”的公式表达赋值给“A1”；其它也是如此。｝
A1:=V>REF(V,1)*3.0;
A2:=V>MA(V,5)*2;
A3:=CROSS(C,MA(C,30));
A4:=C>O;
A5:=A1 AND A2 AND A3 AND A4;
XG: A5;
以上测试通过。
（注：“XG:”—选股执行的意思。）
是不是简明许多。
下面是参数版（测试通过）：
A1:=V>REF(V,1)*N1;
A2:=V>MA(V,N2)*N3;
A3:=CROSS(C,MA(C,N4));
A4:=C>O;
A5:=A1 AND A2 AND A3 AND A4;
XG: A5;
第四讲预告：缩量如何表达？
手把手教你学会编公式之二
作业2:比前一日放量3倍如何表达：
（1）分步1: 今日量能的表达：
Ｖ
（2）分步2: 前一日的量能的表达：
REF—-表示”之前”；
REF(V,1);
(3) 比前一日放量3倍可以表述为：
今日大于前一日量能的3倍：
V>REF(V,1)*3.0;
V>REF(V,1)*N1;
*——表示”乘以”，后面跟数字
（4）放量三倍且上穿30日均线的完形表达：
V>REF(V,1)*3.0 AND CROSS(C,MA(C,30));
V>REF(V,1)*N1 AND CROSS(C,MA(C,N)) ;
好啦，赶紧去试试吧。
三讲预告：把比前一日放量3倍替换为：
今天的量 是5天平均的 2倍以上且收阳；
谢谢。
手把手教你学会编公式之一：介绍入门篇
（注：由于水平有限，又限于对象的理解的原因，可能表达字眼不够专业，见谅。）
我们的目标：一切从实际出发，通过直观的学习，最终理解具体代码的意思，达到自己可以编 写较为实用的公式。要想复杂，还需互相学习促进啦。
1、什么是技术指标？
MA均线就是一种技术指标，我们在炒股的时候，经常会将一些行情数据进行数学计算得出一些曲线等等，方便我们掌握股市的变动情况。
（1）先理解一下基本要素（要求大写）：
（当日）
OPEN —-开盘价，简写：O
HIGH——最高价， H
LOW——-最低价， L
CLOSE—-收盘价， C
VOL———成交量， V
作业1: 股价上穿30日均线，如何表达？
（1）分步1：30日均线：
MA(C,30);
(结尾一定要用“分号”）
——这个表达的意思是：30天内收盘价的平均价格；
“30”可以用参数替代，从而可以有一个宽幅的天数选择范围： MA(C,N);
（2）分步2: 上穿如何表达：
CROSS——穿过、交叉的意思；
（3）分步3: 股价（收盘价）上穿如何表达：
CROSS(C,
（注意：括号一定要有，逗号后面填要上穿的内容，然后括号加分号结束。）
（4）完形表达—股价上穿30日均线：
CROSS(C,MA(C,30));
CROSS(C,MA(C,N));
好啦，这就是一个完整的公式了，已经测试通过。赶紧去试试吧。别忘了设置参数最好。
二讲预告：将依此扩展，加入同时放量怎么表达。
谢谢.
